root/plagger/trunk/lib/Plagger/Plugin/Publish/PodCast.pm

package Plagger::Plugin::Publish::PodCast;

use strict;
use base qw( Plagger::Plugin );

use XML::RSS;
use File::Spec;

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'publish.feed' => \&publish_feed,
    );
}

sub publish_feed {
    my($self, $context, $args) = @_;

    my $f = $args->{feed};
    my $rss = XML::RSS->new( version => '2.0' );
    $rss->channel(
        title       => $f->title,
        link        => $f->link,
        description => $f->description,
    );

    for my $e ($f->entries) {
        $rss->add_item(
            title     => $e->title,
            enclosure => {
                url  => $e->enclosure->url,
                type => $e->enclosure->type,
            },
        );
    }

    # generate file path
    my $filepath = File::Spec->catfile($self->conf->{dir}, $self->gen_filename($f));

    $context->log(info => "save feed for " . $f->url . " to $filepath");

    my $xml = $rss->as_string;
    utf8::decode($xml) unless utf8::is_utf8($xml);
    open my $output, ">:utf8", $filepath or $context->error("$filepath: $!");
    print $output $xml;
    close $output;
}

my %formats = (
    'u' => sub { my $s = $_[0]->url;  $s =~ s!^https?://!!; $s },
    'l' => sub { my $s = $_[0]->link; $s =~ s!^https?://!!; $s },
    't' => sub { $_[0]->title },
    'i' => sub { $_[0]->id },
);

my $format_re = qr/%(u|l|t|i)/;

sub gen_filename {
    my($self, $feed) = @_;

    my $file = $self->conf->{filename} ||
        '%i.' . ($self->conf->{format} eq 'RSS' ? 'rss' : 'atom');
    $file =~ s{$format_re}{
        $self->safe_filename($formats{$1}->($feed))
    }egx;
    $file;
}

sub safe_filename {
    my($self, $path) = @_;
    $path =~ s![^\w\s]+!_!g;
    $path =~ s!\s+!_!g;
    $path;
}

1;