root/plagger/trunk/lib/Plagger/Plugin/Filter/FutureEvents.pm

package Plagger::Plugin::Filter::FutureEvents;

use strict;
use base qw( Plagger::Plugin );
use DateTime;
use Time::Duration::Parse;

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'update.feed.fixup' => \&filter,
    );
}

sub init {
    my $self = shift;
    $self->SUPER::init(@_);

    my $duration = $self->conf->{duration} || 1440; # minutes

    if ($duration =~ /^\d+$/) {
        # if it's all digit, the unit is minutes
        $self->{duration} = $duration * 60;
        return;
    }

    eval { require Time::Duration::Parse };
    if ($@) {
        Plagger->context->error("You need to install Time::Duration::Parse to use human readable timespec");
    }

    $self->{duration} = Time::Duration::Parse::parse_duration($self->{duration});

}

sub filter {
    my($self, $context, $args) = @_;
    my $feed = $args->{feed};

    my @extracted_entries;
    my $now  = DateTime->now( time_zone => $context->conf->{timezone} || 'local' );
    my $then = $now->clone->add( seconds => $self->{duration} );

    for my $entry ( @{$feed->entries} ){
        my $date = $entry->date;
        push @extracted_entries, $entry if $now < $date and $date < $then;
    }

    @{$feed->entries} = @extracted_entries;
}

1;
__END__

=head1 NAME

Plagger::Plugin::Filter::FutureEvents - Extract future events.

=head1 SYNOPSIS

  # events or entries that will occur within a day.
  - module: Filter::FutureEvents
    config:
      duration: 1440

=head1 DESCRIPTION

This rule finds fresh entries or feeds, which means updated date is
within C<duration> minutes. It defaults to 2 hours, but you'd better
configure the value with your cronjob interval.

=head1 CONFIG

=over 1

=item C<duration>

  duration: 5

This rule matches with events that will occur within 5 minutes.

If entries don't have events, check entry->date instead of entry->event->dtstart.

If the supplied value contains only digit, it's parsed as minutes. You
can write in a human readable format like:

  duration: 4 hours

and this module DWIMs. It defaults to I<1440>, which means a day.

=back

=head1 AUTHOR

Gosuke Miyashita

=head1 SEE ALSO

L<Plagger>, L<Time::Duration>

=cut