root/plagger/trunk/lib/Plagger/Plugin/Filter/ConvertVideo.pm

package Plagger::Plugin::Filter::ConvertVideo;

use strict;
use base qw( Plagger::Plugin );
use Encode;
use File::Spec;

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'update.entry.fixup' => \&filter,
    );
}

sub filter {
    my($self, $context, $args) = @_;

    my $e = $args->{entry};

    my $ext = $self->conf->{ext};

    my $file = $e->enclosure->filename;
    $file =~ s/\..*//;

    my $output_file = File::Spec->catfile($self->conf->{output_dir}, "$file.$ext");
    my $encode_type = $self->conf->{encode_type} || 0;

    unless(-e $output_file){
        my $tt = $context->template();
        $tt->process("$encode_type.tt", {
            %{$self->conf},
            entry       => $e,
            output_file => $output_file,
        }, \my $commands) or $context->error($tt->error);

        for (split '\n', $commands){
            system($_);
        }
    }

    $e->enclosure->local_path($output_file);
    $e->enclosure->filename("$file.$ext");
}

1;
__END__

=head1 NAME

Plagger::Plugin::Filter::ConvertVideo - Get a video file of enclosure url and convert it.

=head1 SYNOPSIS

  - module: Filter::ConvertVideo
    config:
      dir: K:\html\www.mizzy.org\cast
      encode_type: 5
      ext: m4v

=head1 DESCRIPTION

This plugin fetches video files of enclosure url, converts them into mpeg4 format, adds converted files to your iTunes and rewrites enclosure url.

This plugin requires 3GP Converter.
http://www.nurs.or.jp/~calcium/3gpp/

=head1 CONFIG

=head2 converter_dir

The directory name that 3GP Converter installed in.Default is C:\Program Files\AVCTest-051105.

=head2 dir

The directory name that converted files put in.

=head2 ext

The extension of converted video file.

=head2 encode type

Specify video encode type.It supports following encode type.

=over 6

=item 0 PSP/AVC QVGA/29.97fps/384kbps

=item 1 PSP/AVC QVGA/29.97fps/VBR QB25

=item 2 PSP/AVC QVGA/29.97fps/384kbps 2pass

=item 3 iPod/AVC QVGA(384kbps)

=item 4 iPod/AVC QVGA(600kbps)

=item 5 iPod/AVC QVGA(600kbps) 2pass

=back

=head1 AUTHOR

Gosuke Miyashita

=head1 SEE ALSO

L<Plagger>

=cut