root/plagger/trunk/lib/Plagger/Plugin/CustomFeed/iTMS.pm

package Plagger::Plugin::CustomFeed::iTMS;
use strict;
use warnings;
use base qw( Plagger::Plugin );

use Plagger::Enclosure;
use LWP::UserAgent::iTMS_Client;
use DateTime::Format::W3CDTF;
use Net::iTMS;

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'subscription.load' => \&load,
    );
}

sub load {
    my($self, $context) = @_;
    my $feed = Plagger::Feed->new;
    $feed->aggregator(sub { $self->aggregate(@_) });
    $context->subscription->add($feed);
}

sub aggregate {
    my($self, $context, $args) = @_;

    my $feed = Plagger::Feed->new;
    $feed->type('iTMSSeach');
    $feed->title('iTMS Search');

    my $ua = LWP::UserAgent::iTMS_Client->new( country => $self->conf->{country} || 'USA' );
    my $itms = Net::iTMS->new;

    my $results = $ua->search( %{$self->conf->{query}} );
    for my $result (@$results){
        my $entry = Plagger::Entry->new;

        $entry->title($result->{itemName});
        $entry->author( $itms->get_artist($result->{artistId}) );
        if($result->{releaseDate}){
            my $dt = DateTime::Format::W3CDTF->parse_datetime($result->{releaseDate});
            $entry->date(Plagger::Date->from_epoch($dt->epoch));
        }

        my $enclosure = Plagger::Enclosure->new;
        $enclosure->url($result->{previewURL});
        $enclosure->auto_set_type;
        $entry->add_enclosure($enclosure);

        $feed->add_entry($entry);
    }

    $context->update->add($feed);
}

1;
__END__

=head1 NAME

Plagger::Plugin::CustomFeed::iTMS - Apple iTunes Music Store CustomFeed

=head1 SYNOPSIS

  - module: CustomFeed::iTMS
    config:
      country: Japan
      query:
        artsit: zebrahead

=head1 DESCRIPTION

This plugin fetches seach results from Apple iTunes Music Store.

=head1 CONFIG

=over 4

=item country

Country name of the store you use.

=item query

Query parameters for searching.

=back

=head1 AUTHOR

Gosuke Miyashita

=head1 SEE ALSO

L<Plagger>, L<LWP::UserAgent::iTMS_Client>, L<Net::iTMS>

=cut