root/plagger/trunk/lib/Plagger/Plugin/CustomFeed/KotonohaInbox.pm

package Plagger::Plugin::CustomFeed::KotonohaInbox;
use strict;
use base qw( Plagger::Plugin );

use Encode;
use WWW::Mechanize;
use Memoize;

memoize('get_icon');

sub plugin_id {
    my $self = shift;
    $self->class_id . '-' . $self->conf->{email};
}

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'subscription.load' => \&load,
    );
}

sub load {
    my($self, $context) = @_;

    my $feed = Plagger::Feed->new;
    $feed->aggregator(sub { $self->aggregate(@_) });
    $context->subscription->add($feed);
}

sub aggregate {
    my($self, $context, $args) = @_;

    my $start = 'http://kotonoha.cc/';

    my $mech = WWW::Mechanize->new(cookie_jar => $self->cache->cookie_jar);
    $mech->agent_alias( 'Windows IE 6' );
    $mech->get($start);

    if ($mech->content =~ /loginform/) {
        my $success;
        eval { $success = $self->login($mech) };

        if ($@) {
            $context->log(error => "Login failed. Clear cookie and redo.");
            $mech->cookie_jar->clear;
            $mech->get($start);
            sleep 3;
            eval { $success = $self->login($mech) };
        }

        return unless $success;
    }

    $context->log(info => "Login to kotonoha succeeded.");

    # get inbox
    $mech->get('http://kotonoha.cc/inbox');

    my $content = decode('utf-8', $mech->content);
    my $re = '<a href="/user/([^>]+)">.+<a href="/no/(\d+)">([^>]+)</a>(.+)\s*</li>';

    my $feed = Plagger::Feed->new;
    $feed->title('kotonoha inbox');
    $feed->link('http://kotonoha.cc');
    $feed->image({
        url  => 'http://kotonoha.cc/images/logo.png',
        link => 'http://kotonoha.cc/',
    });

    while ($content =~ /$re/g) {
        my $entry = Plagger::Entry->new;

        $entry->title($3);
        $entry->body($4);
        $entry->author($1);
        $entry->link("http://kotonoha.cc/no/$2#$1");

        my $icon = $self->get_icon($mech, $1);
        $entry->icon({
            title  => $1,
            url    => $icon->{url},
            link   => $icon->{link},
        });

        $feed->add_entry($entry);
    }
    $context->update->add($feed);
}

sub login {
    my($self, $mech, $retry) = @_;

    $mech->submit_form(
        fields => {
            mail       => $self->conf->{email},
            password   => $self->conf->{password},
            set_cookie => 'on',
        },
    );

    while ($mech->content =~ m!ログむンできたせんでした!) {
        Plagger->context->log(error => "Login to kotonoha failed.");
        return;
    }

    return 1;
}

sub get_icon {
    my ($self, $mech, $user) = @_;

    Plagger->context->log('info', "Getting an icon of $user");
    $mech->get("http://kotonoha.cc/user/$user");
    my $content = decode('utf-8', $mech->content);
    my $re = '<img src="(/upload/profile/.+.jpg)"';

    my $icon;
    while ($content =~ /$re/g) {
        $icon->{url} = "http://kotonoha.cc$1";
        $icon->{title} = $user;
        $icon->{link} = "http://kotonoha.cc/user/$user"
    }

    return $icon;
}

1;
__END__

=head1 NAME

Plagger::Plugin::CustomFeed::KotonohaInbox - Kotonoha Inbox custom feed

=head1 SYNOPSIS

  - module: CustomFeed::KotonohaInbox
    config:
      email: email@example.com
      password: password

=head1 DESCRIPTION

This plugin fetches your inbox data from kotonoha.cc.

=head1 CONFIG

=over 4

=item email, password

Credential you need to login to kotonoha.cc.

=back

=head1 AUTHOR

Gosuke Miyashita

=head1 SEE ALSO

L<Plagger>

=cut