root/plagger/trunk/lib/Plagger/Plugin/CustomFeed/GoogleVideo.pm

package Plagger::Plugin::CustomFeed::GoogleVideo;
use strict;
use warnings;
use base qw( Plagger::Plugin );

use Plagger::Enclosure;
use Plagger::UserAgent;
use XML::Simple;

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'subscription.load' => \&load,
    );
}

sub load {
    my($self, $context) = @_;

    my $feed = Plagger::Feed->new;
    $feed->aggregator(sub { $self->aggregate(@_) });
    $context->subscription->add($feed);
}

sub aggregate {
    my($self, $context, $args) = @_;

    my $q = $self->conf->{query};
    $q =~ s/\s/\+/g;

    my $ua = Plagger::UserAgent->new;
    my $res = $ua->fetch("http://video.google.com/videofeed?type=search&q=$q&output=rss");
    $context->log( error => $res->http_response->status_line ) if $res->is_error;

    my $rss = XMLin( $res->content );

    my $feed = Plagger::Feed->new;
    my $channel = $rss->{channel};
    $feed->type('GoogleVideo');
    $feed->title($channel->{title});
    $feed->link($channel->{link});
    $feed->image({
        url        => $channel->{image}->{url},
        thumb_link => $channel->{image}->{url},
        width      => $channel->{image}->{width},
        height     => $channel->{image}->{height},
    });
    $feed->description($channel->{description});

    my %type = (
        flav => 0,
        wmv  => 1,
        ipod => 2,
        psp  => 3,
    );

    for my $item (@{$rss->{channel}->{item}}){
        my $entry = Plagger::Entry->new;
        $entry->title($item->{title});
        $entry->body($item->{description});
        $entry->id($item->{guid});
        $entry->link($item->{link});
        $entry->date( Plagger::Date->parse('Mail', $item->{pubDate}) );
        $entry->icon({
            url        => $item->{'media:group'}->{'media:thumbnail'}->{url},
            thumb_link => $item->{'media:group'}->{'media:thumbnail'}->{url},
            width      => $item->{'media:group'}->{'media:thumbnail'}->{width},
            height     => $item->{'media:group'}->{'media:thumbnail'}->{height},
        });

        if(ref($item->{'media:group'}->{'media:content'}) eq 'ARRAY'){
            #$entry->meta->{enclosure}->{url} = $item->{'media:group'}->{'media:content'}->[$type{$self->conf->{type}}]->{url};
            #$entry->meta->{enclosure}->{type} = $item->{'media:group'}->{'media:content'}->[$type{$self->conf->{type}}]->{type};
            my $enclosure = Plagger::Enclosure->new;
            $enclosure->url($item->{'media:group'}->{'media:content'}->[$type{$self->conf->{type}}]->{url});
            $enclosure->type($item->{'media:group'}->{'media:content'}->[$type{$self->conf->{type}}]->{type});
            $entry->add_enclosure($enclosure);
        }
        $feed->add_entry($entry);
    }
    $context->update->add($feed);
}

1;
__END__

=head1 NAME

Plagger::Plugin::CustomFeed::GoogleVideo - Get Google Video search result

=head1 SYNOPSIS

  - module: CustomFeed::GoogleVideo
    config:
      query: nba allstar
      type: ipod

=head1 DESCRIPTION

This plugin fetches the result of Google Video search.

=head1 CONFIG

=over 4

=item query

Search query strings.

=item type

Choose a type of video file from flav, wmv, ipod or psp.

=back

=head1 AUTHOR

Gosuke Miyashita

=head1 SEE ALSO

L<Plagger>

=cut